dotfiles/nixng/containers/minecraft/enigmatica-6/default.nix

{inputs, ...}: {
  flake.nixngConfigurations.minecraft-enigmatica-6 = inputs.nixng.nglib.makeSystem {
    system = "x86_64-linux";
    name = "nixng-minecraft";
    inherit (inputs) nixpkgs;
    config = {
      pkgs,
      lib,
      config,
      ...
    }: {
      disabledModules = ["${inputs.nixng}/modules/services/minecraft.nix"];
      imports = [../../../modules/minecraft-curseforge.nix ../../../modules/minecraft.nix];
      dumb-init = {
        enable = true;
        type.services = {};
      };

      nixpkgs.overlays = [inputs.self.overlays.symlink-state];

      _module.args.pkgs = lib.mkForce (import inputs.nixpkgs {
        overlays = [inputs.nixng.overlays.default] ++ (config.nixpkgs.overlays or []);
        system = "x86_64-linux";
        config.allowUnfreePredicate = pkg:
          builtins.elem (lib.getName pkg) [
            "minecraft-curseforge-enigmatica6"
          ];
      });

      init.services.minecraft-curseforge.shutdownOnExit = true;
      services.minecraft.curseforge = {
        enable = true;

        modpackName = "enigmatica6";
        modpackZip = pkgs.fetchzip {
          url = "https://mediafilez.forgecdn.net/files/4915/209/Enigmatica6Server-1.9.0.zip";
          hash = "sha256-5lQTBaycP48b8/XpBhBafjqj55alsi8bMLrp/NxLhMA=";
          stripRoot = false;
        };

        modpacksChHash = "sha256-OHUFVEmRl47hf63LGTWsROEdZSUbCtQICsewPBZF8E0=";

        javaPackage = pkgs.jdk11;

        eulaAccept = true;
      };
    };
  };
}