{lib, ...}: let
  inherit
    (lib)
    singleton
    ;

  pname = "maildrop";
  version = "3.1.5";
in {
  flake.overlays.maildrop = final: prev: {
    maildrop = prev.stdenv.mkDerivation {
      inherit pname version;

      src = prev.fetchurl {
        url = "mirror://sourceforge/courier/${pname}/${version}/${pname}-${version}.tar.bz2";
        sha256 = "sha256-Izg/s5uSaQRWRpOXSO5zfnXJ8jmU+MBnI/MEyXp42lo=";
      };

      nativeBuildInputs = with prev; singleton pkg-config;
      buildInputs = with prev; [
        perl
        pcre2.dev
        libidn2.dev
        courier-unicode
      ];

      patches = [
        ./dont-reset-path.patch
        ./maildrop.configure.hack.patch
      ];

      doCheck = false;

      configureFlags = [
        "--enable-maildrop-uid="
        "--enable-maildrop-gid="
      ];

      meta = with lib; {
        homepage = "http://www.courier-mta.org/maildrop/";
        description = "Mail filter/mail delivery agent that is used by the Courier Mail Server";
        license = licenses.gpl3;
        platforms = platforms.linux;
      };
    };
  };
}