# SPDX-FileCopyrightText: 2022 Richard Brežák <richard@brezak.sk>
#
# SPDX-License-Identifier: LGPL-3.0-or-later
{
  inputs,
  lib',
  config,
  ...
}: let
  inherit
    (lib')
    flip
    mapAttrs
    singleton
    loadSecrets
    mkAfter
    ;

  config' = config;
in {
  flake.nixosConfigurations.omen = inputs.nixpkgs.lib.nixosSystem {
    system = "x86_64-linux";
    lib = lib';

    specialArgs = {
      config' = config';
      inputs' = inputs;
      secret = loadSecrets inputs.secret;
    };

    modules =
      singleton
      ({
        pkgs,
        lib,
        config,
        secret,
        ...
      }: {
        imports = [
          ../../common/steam.nix
          ../../common/sound.nix
          ../../common/remote_access.nix
          ./xserver.nix
          ./grub.nix
          ./networking.nix
          ./filesystems.nix
          ./hardware.nix
          ./users.nix
          ./nixpkgs.nix
          ./firewall.nix
          ./impermenance.nix
          ../../../overlays/ifstate/module.nix
          # ./test-vm.nix

          inputs.uk3s-nix.nixosModules.ucontainers
          inputs.uk3s-nix.nixosModules.ucontainersNetwork
          inputs.notnft.nixosModules.default
          inputs.self.nixosModules.notnft
          inputs.impermenance.nixosModules.impermanence
        ];

        services.fwupd.enable = true;

        services.syncthing = {
          enable = true;
          user = "main";
          group = "main";
        };

        services.sshd.enable = true;

        # Makes QEMU recompile https://github.com/NixOS/nixpkgs/issues/221056
        boot.binfmt.emulatedSystems = [
          "aarch64-linux"
          "riscv64-linux"
          "armv6l-linux"
          "armv7l-linux"
        ];

        environment.systemPackages = [
          pkgs.man-pages-posix
        ];
        documentation.dev.enable = true;

        systemd.services.nix-daemon.environment.SSH_AUTH_SOCK = "/run/user/${toString config.users.users.main.uid}/gnupg/S.gpg-agent.ssh";
        systemd.services.nix-daemon.environment.NIX_SSHOPTS = "-o ControlMaster=auto -o ControlPath=/tmp/nix-daemon-controlmasters/%%r@%%h:%%p -o ControlPersist=300s";

        time.timeZone = "Europe/Amsterdam";
        system.stateVersion = "23.05";

        virtualisation.podman.enable = true;

        virtualisation.podman.defaultNetwork.settings.subnets = [
          {
            gateway = "10.88.0.1";
            subnet = "10.88.0.0/16";
          }
        ];
        virtualisation.podman.dockerCompat = true;
      });
  };
}